V podstate jde o to ze se binarky a ostatni soubory ukladaji do slozky bin.

RUN.BAT

@echo off
 
mkdir bin          >nul 2>&1
mkdir "bin\lst"    >nul 2>&1
mkdir "bin\obj"    >nul 2>&1
mkdir "bin\map"    >nul 2>&1
 
if not exist "bin\obj\%1.obj" goto j1
del "bin\obj\%1.obj"
 
:j1
if not exist "bin\%1.exe" goto j2
del "bin\%1.exe"
 
:j2
if not exist "bin\lst\%1.lst" goto j3
del "bin\lst\%1.lst"
 
:j3
if not exist "bin\map\%1.map" goto j4
del "bin\map\%1.map"
 
:j4
if not exist %1.asm goto input_err
if not exist NASM\NASM.EXE goto no_compiler
echo ============================================================
echo Preklad souboru "%1.asm" pomoci NASM.EXE.
"NASM\NASM.EXE" -f obj %1.asm -l "bin\lst\%1.lst"  -o "bin\obj\%1.obj"
 
if not exist "bin\obj\%1.obj" goto compile_err
if not exist "nasm\LINK.EXE" goto no_linker
 
echo Sestavovani pomoci LINK.EXE:
"nasm\link.exe"  "bin\obj\%1.obj","bin\%1.exe","bin\map\%1.map",,nul.def
 
if not exist "bin\%1.exe" goto link_err
 
echo Spusteni "%1.EXE":
echo ============================================================
echo ------------------------------------------------------------
"bin\%1.EXE"
echo ------------------------------------------------------------
echo ============================================================
echo Program spravne ukoncen, rizeni vraceno operacnimu systemu.
goto exit
 
:input_err
echo ============================================================
	echo Soubor %1.asm neexistuje.
	echo ============================================================
	goto exit
:no_compiler                                
echo ============================================================
	echo Nemohu nalezt program NASM.EXE.
	echo ============================================================
	goto exit
:no_linker
echo ============================================================
	echo Nemohu nalezt program LINK.EXE.
	echo ============================================================
	goto exit
:compile_err
echo ============================================================
	echo Chyba pri prekladu programem NASM.EXE.
	echo ============================================================
	goto exit
:link_err
echo ============================================================
	echo Chyba pri sestavovani programem LINK.EXE.
	echo ============================================================
:exit   
	pause